75 lines
2.3 KiB
Plaintext
75 lines
2.3 KiB
Plaintext
/* $FreeBSD$ */
|
|
OUTPUT_FORMAT("elf64-ia64-little", "elf64-ia64-little", "elf64-ia64-little")
|
|
OUTPUT_ARCH(ia64)
|
|
ENTRY(start)
|
|
kernel_text = 0xe000000004000000;
|
|
SECTIONS
|
|
{
|
|
/* Read-only sections, merged into text segment: */
|
|
. = kernel_text + SIZEOF_HEADERS;
|
|
PROVIDE (btext = .);
|
|
.plt : { *(.plt) }
|
|
.text :
|
|
{
|
|
*(.text .stub .text.* .gnu.linkonce.t.*)
|
|
/* .gnu.warning sections are handled specially by elf32.em. */
|
|
*(.gnu.warning)
|
|
} =0x00300000010070000002000001000400
|
|
_etext = .;
|
|
PROVIDE (etext = .);
|
|
.rodata : { *(.rodata .rodata.* .gnu.linkonce.r.*) }
|
|
.rodata1 : { *(.rodata1) }
|
|
.sdata2 : { *(.sdata2 .sdata2.* .gnu.linkonce.s2.*) }
|
|
.sbss2 : { *(.sbss2 .sbss2.* .gnu.linkonce.sb2.*) }
|
|
.opd : { *(.opd) }
|
|
.IA_64.unwind_info : { *(.IA_64.unwind_info* .gnu.linkonce.ia64unwi.*) }
|
|
.IA_64.unwind : { *(.IA_64.unwind* .gnu.linkonce.ia64unw.*) }
|
|
/* Adjust the address for the data segment. We want to adjust up to
|
|
the same address within the page on the next page up. */
|
|
. = . + 8192;
|
|
.data :
|
|
{
|
|
*(.data.proc0 .data .data.* .gnu.linkonce.d.*)
|
|
SORT(CONSTRUCTORS)
|
|
}
|
|
.data1 : { *(.data1) }
|
|
.dynamic : { *(.dynamic) }
|
|
. = ALIGN(16);
|
|
__gp = . + 0x200000;
|
|
.got : { *(.got.plt) *(.got) }
|
|
.IA_64.pltoff : { *(.IA_64.pltoff) }
|
|
/* We want the small data sections together, so single-instruction offsets
|
|
can access them all, and initialized data all before uninitialized, so
|
|
we can shorten the on-disk segment size. */
|
|
.sdata :
|
|
{
|
|
*(.sdata .sdata.* .gnu.linkonce.s.*)
|
|
}
|
|
_edata = .;
|
|
PROVIDE (edata = .);
|
|
__bss_start = .;
|
|
.sbss :
|
|
{
|
|
PROVIDE (__sbss_start = .);
|
|
PROVIDE (___sbss_start = .);
|
|
*(.dynsbss)
|
|
*(.sbss .sbss.* .gnu.linkonce.sb.*)
|
|
*(.scommon)
|
|
PROVIDE (__sbss_end = .);
|
|
PROVIDE (___sbss_end = .);
|
|
}
|
|
.bss :
|
|
{
|
|
*(.dynbss)
|
|
*(.bss .bss.* .gnu.linkonce.b.*)
|
|
*(COMMON)
|
|
/* Align here to ensure that the .bss section occupies space up to
|
|
_end. Align after .bss to ensure correct alignment even if the
|
|
.bss section disappears because there are no input sections. */
|
|
. = ALIGN(64 / 8);
|
|
}
|
|
. = ALIGN(64 / 8);
|
|
_end = .;
|
|
PROVIDE (end = .);
|
|
}
|