11e7b38f4b
it will work (so long as it is not too close to zero, and a 4 byte aligned address of course).
111 lines
3.1 KiB
ArmAsm
111 lines
3.1 KiB
ArmAsm
|
|
;@-------------------------------------------------------------------------
|
|
;@-------------------------------------------------------------------------
|
|
|
|
.globl _start
|
|
_start:
|
|
b reset
|
|
ldr pc,undefined_handler
|
|
ldr pc,swi_handler
|
|
ldr pc,prefetch_handler
|
|
ldr pc,data_handler
|
|
ldr pc,unused_handler
|
|
ldr pc,irq_handler
|
|
ldr pc,fiq_handler
|
|
undefined_handler: .word hang
|
|
swi_handler: .word hang
|
|
prefetch_handler: .word hang
|
|
data_handler: .word hang
|
|
unused_handler: .word hang
|
|
irq_handler: .word irq
|
|
fiq_handler: .word hang
|
|
|
|
text_size_x: .word text_size
|
|
soffset: .word reset - _start + 8
|
|
|
|
reset:
|
|
mov r0,pc
|
|
ldr r1,soffset
|
|
sub r0,r1
|
|
cmp r0,#0
|
|
beq skip_copy
|
|
mov r1,#0;
|
|
ldr r2,text_size_x
|
|
add r2,r2,#0xFF
|
|
add r2,r2,#15
|
|
mov r2,r2,lsr #4
|
|
copy_loop:
|
|
ldmia r0!,{r4,r5,r6,r7}
|
|
stmia r1!,{r4,r5,r6,r7}
|
|
subs r2,r2,#1
|
|
bne copy_loop
|
|
mov r0,#0
|
|
bx r0
|
|
|
|
skip_copy:
|
|
|
|
;@ (PSR_IRQ_MODE|PSR_FIQ_DIS|PSR_IRQ_DIS)
|
|
mov r0,#0xD2
|
|
msr cpsr_c,r0
|
|
mov sp,#0x6000000
|
|
|
|
;@ (PSR_FIQ_MODE|PSR_FIQ_DIS|PSR_IRQ_DIS)
|
|
mov r0,#0xD1
|
|
msr cpsr_c,r0
|
|
mov sp,#0x7000000
|
|
|
|
;@ (PSR_SVC_MODE|PSR_FIQ_DIS|PSR_IRQ_DIS)
|
|
mov r0,#0xD3
|
|
msr cpsr_c,r0
|
|
mov sp,#0x8000000
|
|
|
|
;@ SVC MODE, IRQ ENABLED, FIQ DIS
|
|
;@mov r0,#0x53
|
|
;@msr cpsr_c, r0
|
|
|
|
bl notmain
|
|
hang: b hang
|
|
|
|
.globl PUT32
|
|
PUT32:
|
|
str r1,[r0]
|
|
bx lr
|
|
|
|
.globl GET32
|
|
GET32:
|
|
ldr r0,[r0]
|
|
bx lr
|
|
|
|
.globl dummy
|
|
dummy:
|
|
bx lr
|
|
|
|
.globl enable_irq
|
|
enable_irq:
|
|
mrs r0,cpsr
|
|
bic r0,r0,#0x80
|
|
msr cpsr_c,r0
|
|
bx lr
|
|
|
|
irq:
|
|
push {r0,r1,r2,r3,r4,r5,r6,r7,r8,r9,r10,r11,r12,lr}
|
|
bl c_irq_handler
|
|
pop {r0,r1,r2,r3,r4,r5,r6,r7,r8,r9,r10,r11,r12,lr}
|
|
subs pc,lr,#4
|
|
|
|
;@-------------------------------------------------------------------------
|
|
;@-------------------------------------------------------------------------
|
|
|
|
;@-------------------------------------------------------------------------
|
|
;@
|
|
;@ Copyright (c) 2012 David Welch dwelch@dwelch.com
|
|
;@
|
|
;@ Permission is hereby granted, free of charge, to any person obtaining a copy of this software and associated documentation files (the "Software"), to deal in the Software without restriction, including without limitation the rights to use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies of the Software, and to permit persons to whom the Software is furnished to do so, subject to the following conditions:
|
|
;@
|
|
;@ The above copyright notice and this permission notice shall be included in all copies or substantial portions of the Software.
|
|
;@
|
|
;@ THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
|
|
;@
|
|
;@-------------------------------------------------------------------------
|
|
|